;;345678901234567890123456789012345678901234567890123456789012345678901234567890
;;**********
;;* logexp2.asm: base-2 logarithm and exponent
;;* Copyright 2003 Duane K. Wise
;;**********

	org	l:
log2Tab	dc	-1023087329808,5577163454524,-17541124758042
	dc	43328084931985,-78540235168623,103513368583182
	dc	-98107481863207,65200444954112,-28861715242043
	dc	7647611088685,-918150744020
exp2Tab	dc	70368744355749,48775879188841,16904715390224
	dc	3904102273128,681464029041,87196245988,15386678159
dreg0	ds	1
dreg1	ds	1
dreg2	ds	1


	org	p:
;;**********
;;* Function:	log2 - base-2 logarithm, double-precision
;;* Input:	a - signed 9.47 linear value (overflow bits are significant)
;;* Output:	a - signed 7.41 base-2 logarithm of input
;;* Consumed:	b,x,y,r5
;;* Notes:	assumed m5 is set to -1
;;*		the log of zero or less is returned as -48.0,
;;*		else there is about 36 bits of accuracy in the result (7.29)
;;*		it is OK to round the result to single-precision
;;**********
log2:
	tst	a
	ble	<log0
	move			#log2Tab,r5
	clb	a,b
	normf	b1,a
	move				b1,x:dreg2
	move					a,l:dreg0
	move					a,l:dreg1
	move					l:(r5)+,a
	do	#10,logLoop
	    move				l:dreg1,x
	    move				l:(r5)+,y
	    mpyuu x0,y0,b
	    dmacsu x1,y0,b
	    macsu y1,x0,b
	    dmacss x1,y1,b
	    add	 b,a				l:dreg0,y
	    mpyuu x0,y0,b
	    dmacsu x1,y0,b
	    macsu y1,x0,b
	    dmacss x1,y1,b
	    move				b,l:dreg1
logLoop:
	move				x:dreg2,b
	asl	#3,a,a
	sub	#1,b
	asl	#17,b,b
	add	b,a
	rts
log0:
	move			#<$a0,a
	rts


;;**********
;;* Function:	exp2 - base-2 exponent, double-precision
;;* Input:	a - signed 7.41 logarithmic value
;;* Output:	a - unsigned 17.39 base-2 exponent of input
;;*		(overflow bits are significant)
;;* Consumed:	b,x,y,r5
;;* Notes:	assumes m5 is set to -1
;;*		the output is limited to the end of the overflow word,
;;*		so bit 55 should always be zero
;;*		17.39 in the accumulator means that the effective value
;;*			is the normal fractional normalized with a right-shift
;;*			by 8--using the output requires a compensating
;;*			left shift
;;*		there is about 29 bits of accuracy in the output mantissa
;;*		it is OK to round the result to single-precision
;;**********
exp2:
	asr	#17,a,b
	asl	#7,a,a
	move			#<0,b0
	move			#<0,a2
	neg	b
	asr	a		#exp2Tab,r5
	add	#7,b
	move					a,l:dreg0
	move					a,l:dreg1
	move				b1,x:dreg2
	move					l:(r5)+,a
	do	#6,expLoop
	    move				l:dreg1,x
	    move				l:(r5)+,y
	    mpyuu x0,y0,b
	    dmacsu x1,y0,b
	    macsu y1,x0,b
	    dmacss x1,y1,b
	    add	 b,a				l:dreg0,y
	    mpyuu x0,y0,b
	    dmacsu x1,y0,b
	    macsu y1,x0,b
	    dmacss x1,y1,b
	    move				b,l:dreg1
expLoop:
	move				x:dreg2,b
	move			#>-8,x0
	cmp	x0,b
	tle	x0,b
	normf	b1,a
	rts